برگهٔ خلاصه

// One program that uses most of the syntax on one page.
indicator "Cheat sheet"
    edition = 1
    display = price

enum Kind
    sma = "SMA"
    ema = "EMA"

type Band
    upper: float
    lower: float

group "Average"
    /// How many bars the average reads
    input length: int = 20, name = "Length", min = 2, max = 500
    input kind: Kind = Kind.ema, name = "Kind"
    input src: source = close, name = "Source"
input width: float = 2.0, name = "Width", min = 0.1, step = 0.1
input band_color: color = #2962ff, name = "Band colour"

session london = 08:00 .. 16:30 @ "Europe/London"

fn band_of(middle: float, size: float): Band = Band(upper = middle + size, lower = middle - size)

let sma = tech.sma(src, length)
let ema = tech.ema(src, length)
let middle = match kind
    Kind.sma => sma
    Kind.ema => ema
let b = band_of(middle, width * tech.atr(length))
state above_count = 0
mut last_three = 0.0
for i in 0 until 3
    last_three += close[i]
if close > b.upper
    above_count += 1
let crossed = tech.crosses_above(close, middle)
let top = plot(b.upper, name = "Upper", color = band_color)
let bottom = plot(b.lower, name = "Lower", color = band_color)
shade(top, bottom, color = color.fade(band_color, 90), name = "Band")
plot(middle, name = "Middle", color = color.gray, width = 2)
plot(last_three / 3, name = "Mean of 3 closes", display = none)
mark.shape(crossed, name = "Cross up", shape = triangle_up, place = below, color = color.green)
chart.background(if london.active then color.fade(color.blue, 94) else na, name = "London")
let yesterday_high = prior(day).high
plot(yesterday_high, name = "Yesterday's high", style = step_break, color = color.orange)
if bar.is_last
    label.new(
        bar.index,
        b.upper,
        f"{above_count} closes above, last {close:price}",
        style = label_down,
    )

// A strategy: orders with a key, a stop and a target, size and costs in the header.
strategy "Cheat sheet strategy"
    edition = 1
    display = price

setup:
    capital = 10000
    size = sizing.lots(0.1)
    fees = fee.per_lot(3.5)

execution:
    spread = 20 ticks
    slippage = 2 ticks

let fast = tech.ema(close, 10)
let slow = tech.ema(close, 30)
if tech.crosses_above(fast, slow)
    orders.enter("Long", side.long)
if position.size > 0
    orders.exit("Exit", "Long", stop = position.avg_price * 0.99, limit = position.avg_price * 1.02)
if tech.crosses_below(fast, slow)
    orders.close("Long")
plot(fast, name = "Fast", color = color.green)
plot(slow, name = "Slow", color = color.red)